Month: November 2003

Pasirodė populiaros Perlo distribucijos Windows platformai ActivePerl
versija. Ši versija yra kurta 5.8.1 Perlo versijos pagrindu ir turi
nemažai atnaujintų modulių. Patys didžiausi atnaujinti moduliai yra
XML::Parser ir Archive::Tar. Visi ActivePerl
vartotojai turbūt turėtų atsinaujinti Perlo versijas į šią naująją.

Kai kam prireikė funkcijos, kuri
verstų skaičius į lietuvių kalbą. Tad parašiau Perlinį moduliuką –
gal bus dar kam nors naudingas. (Parsiųsti kaip normalų modulį galima iš
čia)

#!/usr/bin/perl -w
package Num2LTWord;

=head1 Num2LTWord -- skaičiai lietuviškai

Modulis verčiantis (sveikus) skaičius į lietuvių kalbą

=head2 NAUDOJIMAS

    use Num2LTWord;
    num2ltword(2003);

=head2 FUNKCIJOS

=head3 num2ltword ( skaičius )

Ši funkcija grąžina suformuotą lietuvišką skaičiaus pavadinimą.

=head2 RIKTAI IR APRIBOJIMAI

Funkcija C<num2ltword> supranta tik sveikus skaičius intervale
(- 1 000 000 000; 1 000 000 000)

=head2 AUTORIUS

Petras Kudaras aka moxliukas (moxliukas@delfi.lt)

=cut

use strict;
use warnings;
use Exporter;
our @ISA = qw/Exporter/;
our @EXPORT = qw/num2ltword/;
our $VERSION = 0.02;

sub num2ltword {
    my $ka = shift;
    my $result = '';

    return "Nežinau kaip čia paverst" unless $ka eq int($ka);
    return "nulis" if $ka == 0;
    my $kam = abs $ka;
    $result .= "minus " if $ka < 0;
    if($kam >= 1_000_000_000) {
        return "Per didelis man čia skaičius";
    } else {
        $result .= __iki1e9($kam);
        $result =~ s/\s+$//;
        $result =~ s/\s+/ /g;
        return $result;
    }
}

sub __iki10 {
    my $ka = shift;
    my @skaitmenys =     ("", "vienas", "du",
                 "trys", "keturi", "penki",
                 "šeši", "septyni", "aštuoni",
                 "devyni", "dešimt");
    return $skaitmenys[$ka];
}

sub __iki20 {
    my $ka = shift;
    my @lika =     ("vienuolika", "dvylika", "trylika",
             "keturiolika", "penkiolika", "šešiolika",
             "septyniolika", "aštuoniolika", "devyniolika");
    if ($ka <= 10) {
        return __iki10($ka);
    } else {
        return $lika[$ka % 10 - 1];
    }
}

sub __iki100 {
    my $ka = shift;
    my @desimt = ("", "", "dvi", "tris", "keturias", "penkias",
            "šešias", "septynias", "aštuonias", "devynias");
    if ($ka < 20) {
        return __iki20($ka);
    } else {
        if($ka % 10 == 0) {
            return $desimt[int($ka/10)] . "dešimt";
        } else {
            return $desimt[int($ka/10)] . "dešimt " . __iki10($ka % 10);
        }
    }
}

sub __iki1000 {
    my $ka = shift;
    return __iki100($ka) if ($ka < 100);
    if(int($ka / 100) == 1) {
        return __iki10(int($ka/100)) . " šimtas " . __iki100($ka % 100);
    } else {
        return __iki10(int($ka/100)) . " šimtai " . __iki100($ka % 100);
    }
}

sub __iki1e6 {
    my $ka = shift;
    return __iki1000($ka) if ($ka < 1000);
    my $t = __iki1000(int($ka/1000));
    if ($t =~ /vienas$/) {
        return "$t tūkstantis " . __iki1000($ka % 1000);
    } elsif ($t =~ /(?:lika|šimtai|imt)\s*$/) {
        return "$t tūkstančių " . __iki1000($ka % 1000);
    } else {
                return "$t tūkstančiai " . __iki1000($ka % 1000);
    }
}

sub __iki1e9 {
    my $ka = shift;
        return __iki1e6($ka) if ($ka < 1_000_000);
        my $t = __iki1e6(int($ka/1_000_000));
        if ($t =~ /vienas$/) {
                return "$t milijonas " . __iki1e6($ka % 1_000_000);
        } elsif ($t =~ /(?:šimtai|lika|imt)\s*$/) {
                return "$t milijonų " . __iki1e6($ka % 1_000_000);
        } else {
                return "$t milijonai " . __iki1e6($ka % 1_000_000);
        }
}                                                   
1;

Labai įdomus dalykas, kurį šiandien aptikau benaršydamas internetą
buvo Internet Explorerio featuras, kurio pagalba galima
išsikviesti Notepad. Tereikia parašyti kažką panašaus į:

<img 
src="view-source:file:///C:/WINNT/system32/shell32.dll">

Ir jei jūsų Windows sėdi kataloge C:WINNT, greit pajausite kaip
Notepad pradeda prakaituoti stengdamasis parodyti bylą
shell32.dll. O juk galima įdėti ir kelias tokia nuorodas ir
staiga swape gali atsirasti kokia pora gigabaitų duomenų. Įdomu
dar ir tai, kad tokių dalykų nepagauna jokios Popup blokavimo
programos. Tiesiog tai vienas iš Internet Explorer featurų. :-) (Plačiau
– http://computerbytesman.com/security/notepadpopups.htm)

Šiandien pietaudamas nubluejackinau antrą žmogų. Vėlgi Nokijos
turėtojas, tačiau šį kartą ne jaunutė mergina, o gana pagyvenęs
kostiumuotas verslininkas. Labai buvo įdomi jo reakcija: viską jis
priėmė labai natūraliai (na, aš jam tik pasiunčiau „you have been
bluejacked“) ir ramiai. Parodė savo partneriui savo telefoną ir
pasakė „tos reklamos visur jau lenda“. Matyt žmogus nulipęs
nuo Internet Explorerio su šokinėjančiais langais.

Pridėjau šiandien į perl-dev CVS kodo testus. Šiaip atrodo Lietuvoje niekas lyg ir
nedaro web aplikacijų kartu su testais (test based programming), nors
Perlmonksuose teko girdėti apie tai nemažai. Esmė yra tame, kad pakeitus
kažkokį failą automatiškai prasitestuojama ar viskas veikia kaip ir
turėtų, ar tie pakeitimai nesugriovė kokio nors kodo kuris seniau jau
veikė. Šiek tiek gal ir su eXtreme Programming susiję (ten pradžioj
parašomas testas kuris neveikia, o paskui stengiamasi padaryt kad jis
veiktų). Na, žiūrėsim kaip čia bus ir ar bus iš to naudos. Pagrindinis
šių testų tikslas (bent jau man atrodytų) būtų automatiškas patikrinimas
ar visa svetainė validuojasi su W3C validatoriais (tam parašiau labai
paprastą funkciją, kurią galima rasti perl-dev/src/lib/W3Validate.pm)

Visi testai sėdi direktorijoje src/t/* – pirmasis
tik patikrina ar yra visos bylos savo vietose ir ar jas įmanoma
nuskaityti (o jei jos baigiasi .pl arba .t
– ar galima jas vykdyti), kitas patestuoja dhandler, o
trečias – autohandler (tiksliau index.html).
Testus galima paleisti arba iš src/t/ direktorijos po
vieną, arba visus iš karto skriptu ./runtests.pl (arba per
Makefile – make test)

Visus šiuos pakeitimus galima atsisiųsti per CVS arba čia
(tiesa, kol kas extractina į ‘.’ o ne į ‘perl-dev’ — jei bus
skundų tai pakeisiu

Turėjau šiokių problemų su perlific, mat jeigu jis kurį
laiką nevykdydavo jokios MySQL užklausos, MySQL uždarydavo ryšį su perlu
ir duomenų bazė tapdavo nebepasiekiama. Norint išlaikyti atvirą jungtį
su MySQL reikia kas kažkiek laiko papinginti duombazę
iškviečiant $dbh->ping();. Tai galima padaryti keleta
būdu (juk čia Perlas): fork()‘int ir atskirame procese
daryti while(1) { sleep(60); $dbh->ping(); }, galima
naudotis gijomis (jei Perlas kompiliuotas su jomis) – use
threads;, galima apsirašyti funkciją on_ping (nes juk
tai IRC botas). Padariau dar kitaip. Štai tas kodas:

$SIG{ALRM} = \&on_alarm;
alarm(60);
sub on_alarm {
        $dbh->ping;
        $SIG{ALRM} = \&on_alarm;
        alarm(60);
}

Šis kodo gabaliukas aprašo funkciją, kuri turi būti iškviečiama kai
gaunamas sisteminis signalas SIGALARM. Paskui su alarm(60)
nurodoma operacinei sistemai kad ji praneštų kai praeis 60 sekundžių.
Pačioje funkcijoje reikia iš naujo nurodyti SIGALARM funkciją ir laiko
tarpą. Gaunasi poor man’s multithreading.